//particlePainter.mel by Eric Keller 2/2007
//sketch particles on a surface, several different particle objects
//select the particles and run the script
//will allow you to keyframe radius of particles as they
//grow along the surface based on their particle ID
//use growMe attribute on each particle to keyframe the 
//growth

//tutorial available on www.bloopatone.com

pickWalk -d down;
string $mySel[]=`ls -sl`;

//create scale multiplier control on a locator
spaceLocator -n particleScaleMult;
addAttr -ln scaleUp -at double -keyable true particleScaleMult;
setAttr "particleScaleMult.scaleUp" 1;

//start loop to add expressions to the particles

for ($i=0; $i<size($mySel); $i++){

	//add scalar attribute to control overall growth
	addAttr -ln growMe -at double $mySel[$i];
	setAttr -e -keyable true ($mySel[$i] + ".growMe");

	//add radiusPP attribute
	addAttr -ln radiusPP -dt doubleArray $mySel[$i];
	addAttr -ln radiusPP0 -dt doubleArray $mySel[$i];

	//add growRate attribute
	addAttr -ln growRate -dt doubleArray $mySel[$i];

	//add maxSize attribute
	addAttr -ln maxSize -dt doubleArray $mySel[$i];


	//add creation expressions
	dynExpression -s "seed(particleId);\r\n radiusPP=0;\r\n growRate=rand(.01,.05);\r\n maxSize=rand(.01,.05);" -c $mySel[$i];

	//add runtime expressions
	dynExpression -s "maxSize=maxSize*particleScaleMult.scaleUp;\r\nif (particleId>growMe){\r\n\tradiusPP=0;\r\n}\r\nelse\r\n{\r\n\tradiusPP=clamp(0,maxSize,radiusPP+growRate);\r\n}"-rbd $mySel[$i];
		
	//set keyframes on growMe
	currentTime 0;
	setAttr ($mySel[$i]+".growMe") -1;
	setKeyframe ($mySel[$i]+".growMe");
	currentTime 200;
	float $partCount=`getAttr ($mySel[$i] + ".count")`;
	setAttr ($mySel[$i]+".growMe") $partCount;
	setKeyframe ($mySel[$i]+".growMe");

	//set particle render type to blobby surface
	setAttr ($mySel[$i] + ".particleRenderType") 7;

};