Painting With Particles
By Eric Keller
copyright 2007 Bloopatone

Part Two: Automating the setup using MEL

Ok, so that was a bit of fun. Well, actually it was tedious. In this section we'll remove the tedium by creating a MEL script that will create the control attributes and automatically apply all the expressions to any number of particle objects. So in the future you can paint your particles on a surface, select the particle objects, run the script, and then make any adjustments you need to make on the graph editor. This version of the script has no interface, its a just a simple loop. Hopefully in the future I'll have time to create a more elegant version.

Step 1: Open a text editor or your favorite MEL scripting environment.

Step 2: The first line of the script is our ever popular selection array.

string $mySel[] = `ls -sl`;

This places all of the selcted objects into a list in the order in which they were selected (ls="list", sl="selected"). This list is contained in the $mySel[] string array variable. The index list starts at 0 and counts up until the array is complete. So if you have three particle objects selected when you run this line $mySel will contain the three particle objects. The first particle object will have an index of 0, the second will have an index of 1, and the third will have an index of 2. Confusing? Not really as long as you remember the list starts at 0. If you want to access the second particle object in the array you would type $mySel[1];.

Step 3: OK, we have to back up a little. If you remember, the custom attributes and expressions are applied to the shape node of the particle objects. This means the user has to remember to pick the particle shape nodes in the Outliner before applying the script. This is kind of annoying. It might be nice if the script automatically picked the particle shape node even when the user has selected the particle's transform node. An easy way to fix this is to use the pickWalk command to move down in the hierarchy. This means that if the user selects a bunch of particle objects, the script will move down from the transform node of each particle and select the shape node and then fill the $mySel array with the particle shape nodes. Its not a bullet-proof solution but it should work for now. So lets edit the script so that now the first  two lines read:

pickWalk -d down;
string $mySel[]=`ls -sl`;

If the user already has the shape node of the particles selected, not to worry, the pickWalk command won't do anything to affect the selection (unless there is something parented to the particle shape node, but that is highly unlikely).

Step 4: In the last part of section 1 of this tutorial we created a locator that added a multiplier to the maxSize attribute of the particles. Since this attribute will be referenced in the script we should add it now before starting the loop. We'll also set the attribute to 1. If we leave it at zero it will cancel out the scale of the particles and nothing will happen when we run the script.

//create scale mulitplier control on locator.
spaceLocator -n particleScaleMult;
addAttr -ln scaleUp -at double -keyable true particleScaleMult;
setAttr "particleScaleMult.scaleUp" 1;

The -at flag sets the attribute type. In this case it is a double which is similar to a float vlaue type.

Step 5: Now we'll start the loop which will run once for each object we have selected. To do this we set the loop iterations to the size of $mySel.

//start loop to add expressions to the particles

for ($i=0; $i<size($mySel); $i++){

    //add scalar attribute to control overall growth
    addAttr -ln growMe -at double $mySel[$i];
    setAttr -e -keyable true ($mySel[$i] + ".growMe");

    //add radiusPP attribute
    addAttr -ln radiusPP -dt doubleArray $mySel[$i];
    addAttr -ln radiusPP0 -dt doubleArray $mySel[$i];

    //add growRate attribute
    addAttr -ln growRate -dt doubleArray $mySel[$i];
   
    //add maxSize attribute
    addAttr -ln maxSize -dt doubleArray $mySel[$i];

Step 6: Next we'll add the expressions. The \r and \n flags just add returns and newlines in the expression eitor which will make it easier to read if we need to edit the expressions.(\t= "tab"). Note that the -c flag and the -rbd flags for the dynExpressions tell maya that the expressions is either "creation" or "runtime before dynamics".

    //add creation expressions
    dynExpression -s "seed(particleId);\r\nradiusPP=0;\r\n growRate=rand(.01,.05);\r\n maxSize=rand(.01,.05);" -c $mySel[$i];

    //add runtime expressions
    dynExpression -s "maxSize=maxSize*particleScaleMult.scaleUp;\r\nif(particleId>growMe){\r\n\t radiusPP=0;\r\n}\r\n else \r\n{\r\n \t radiusPP=clamp(0,maxSize,radiusPP+growRate);\r\n}"-rbd $mySel[$i];

Step 7: Now we can add a few time saving devices. If we put some initial keyframes on the growMe attribute for each particle, and base it on the count for each particle shape selected, we won't have to go back and do this manually once all the particle expressions have been applied. We can jsut select each particle group and adjust the keyframes on the graph editor. We'll set the initial keyframe on growMe to -1. This eliminates the possibility of a single particle popping up on frame 1 of the animation (remember, the if statement says particleId>growMe, if growMe and particleId are both 0 the expression may evaluate as if particleId is less than growMe, meaning you'll have one particle scaled up at the start of your brush stroke).

//set keyframes on growMe
currentTime 0;
setAttr ($mySel[$i]+".growMe") -1;
setKeyframe (mySel[$i]+".growMe");
currentTime 200;
float $partCount=`getAttr ($mySel[$i]+".count")`;
setAttr ($mySel[$i]+"."growMe") $partCount;
setKeyframe ($mySel[$i]+".growMe");

Step 8: Finally we'll just set the particle render type to blobby surface as a mtter of convenience to the user.

//set particle render type to blobby surface
setAttr ($mySel[$i]+".particleRenderType") 7;

}

OK, that's the script. Look it over again for typos and then save it as particlePainterEK.mel in your scripts directory. Open a new file and use the particle tool to sketch some particles on the grid or on a surface. Make several different particle objects (hit the enter key to finish a stroke and then choose the particle tool and draw some new particles). Copy and paste the script into the script editor, select the particle objects and hit enter. If all goes well you should be able to play the animation and see your particles grow whereever you've painted them.

<<warning - I type like a monkey so if you've followed along writing the script exactly as it appears on this page and you're getting a lot of errors, download this version of the script and compare it to what you've written. I've tested it and it does work>>


Part Three: Expanding the Script

Home